Jacoco

plugins {
    id 'org.springframework.boot' version '2.3.1.RELEASE'
    id 'io.spring.dependency-management' version '1.0.9.RELEASE'
    id 'java'

		// 플러그인에 Jacoco 추가
    id 'jacoco'
}

group = 'wooteco.team.ittabi'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '1.8'

jacoco {
    toolVersion = '0.8.5'
}

// html로 쉽게 보여줄 수 있도록 해주는 리포트 설정
jacocoTestReport {
    reports {
        html.enabled true
        xml.enabled false
        csv.enabled false
    }

		// 리포트를 먼저 설정해주고 jacocoTestCoverageVerification를 실행합니다.
    finalizedBy 'jacocoTestCoverageVerification'
}

jacocoTestCoverageVerification {
    violationRules {
        rule {
            enabled = true
						// BUNDLE은 전체를 뜻함. 전체 단위로 아래 limit 규칙을 적용하겠다~
            element = 'BUNDLE'

            limit {
								// 보통 디폴트로 INSTRUCTION를 함
                counter = 'INSTRUCTION'
                value = 'COVEREDRATIO'
                minimum = 0.80
            }

            limit {
								// if와 같은 조건문의 커버리지
                counter = 'BRANCH'
                value = 'COVEREDRATIO'
                minimum = 0.70
            }

						// 제외시킬 파일들. 전체라서 굳이 exclude하지 않았음
            excludes = []
        }

        rule {
            enabled = true
						// 클래스 단위로 아래 limit 규칙을 적용하겠다~
            element = 'CLASS'

            limit {
                counter = 'BRANCH'
                value = 'COVEREDRATIO'
                minimum = 0.50
            }

						// 제외시킬 파일들
            excludes = [
                    '*.mailauth.*',
                    '*.config.*',
                    '*.MailAuthService',
                    '*.aws.*',
                    'wooteco.team.ittabi.legenoaroundhere.domain.award.PopularityPostCreatorAward',
            ]
        }
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.apache.tika:tika-core:1.22'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'io.springfox:springfox-swagger2:2.9.2'
    implementation 'io.springfox:springfox-swagger-ui:2.9.2'
    implementation 'com.sun.mail:javax.mail:1.6.0'
    implementation 'org.springframework:spring-context-support:5.0.1.RELEASE'
    implementation 'io.jsonwebtoken:jjwt:0.9.1'
    implementation platform('com.amazonaws:aws-java-sdk-bom:1.11.832')
    implementation 'com.amazonaws:aws-java-sdk-s3'
    implementation 'org.flywaydb:flyway-core'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.security:spring-security-oauth2-client'

    testImplementation 'io.rest-assured:rest-assured'
    testImplementation 'org.springframework.security:spring-security-test'
    testImplementation 'io.rest-assured:rest-assured'
    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude group: 'org.junit.vintage', module: 'junit-vintage-engine'
    }

    runtimeOnly 'com.h2database:h2'
    runtimeOnly("mysql:mysql-connector-java:8.0.17")

    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'
}

test {
    useJUnitPlatform()
		// 테스트를 하고 jacocoTestReport를 하겠다~
    finalizedBy 'jacocoTestReport'
}